home *** CD-ROM | disk | FTP | other *** search
/ Network PC / Network PC.iso / amiga utilities / communication / internet / amitcp3.0b / src.lha / src / amitcp / netinet / in_cksum.asm < prev    next >
Encoding:
Assembly Source File  |  1996-09-08  |  3.5 KB  |  204 lines
  1. ;;; $Id: in_cksum.asm,v 1.2 1994/02/17 18:35:54 jraja Exp $
  2. ;;;
  3. ;;; in_cksum.s --- calculate internet checksum
  4. ;;;
  5. ;;; Author: ppessi <Pekka.Pessi@hut.fi>
  6. ;;;
  7. ;;; Copyright (c) 1993 AmiTCP/IP Group, <amitcp-group@hut.fi>,
  8. ;;;                    Helsinki University of Technology, Finland.
  9. ;;;
  10. ;;; Created      : Wed Oct 20 08:55:45 1993 ppessi
  11. ;;; Last modified: Thu Oct 21 03:18:26 1993 ppessi
  12. ;;;
  13. ;;; $Log: in_cksum.asm,v $
  14. ;; Revision 1.2  1994/02/17  18:35:54  jraja
  15. ;; Added __regargs entry point.
  16. ;;
  17. ;; Revision 1.1  1993/10/21  01:59:45  ppessi
  18. ;; Initial revision
  19. ;;
  20. ;; Revision 1.1  1993/10/21  01:59:45  ppessi
  21. ;; Initial revision
  22. ;;
  23. ;;;
  24.  
  25.     INCLUDE   "sys/mbuf.i"
  26.  
  27.     XREF    _printf
  28.     XDEF    _in_cksum
  29.     XDEF    @in_cksum
  30.  
  31. ** stack offsets for __stdargs
  32. m_off        set    $4
  33. len_off        set    $8
  34.  
  35. ** registers for __regargs
  36. m_reg        equr    a0
  37. len_reg         equr    d0
  38.  
  39. m        equr    a0
  40. w        equr    a1
  41. end        equr    a2
  42.  
  43. len        equr    d7
  44. mlen        equr    d6
  45. sum        equr    d5
  46. zero        equr    d4
  47. spanning    equr    d3
  48. byte_swapped    equr    d2
  49.  
  50.         section      text,code
  51. _in_cksum:
  52.         move.l    m_off(sp),m_reg
  53.         move.l  len_off(sp),len_reg 
  54. @in_cksum:
  55.         movem.l d2-d7/a2/a3/a5/a6,-(sp)
  56. * a0 to a0    move.l  m_reg,m
  57.         move.l    len_reg,len
  58.         moveq    #0,sum
  59.         move.l    sum,spanning
  60.         move.l    sum,zero
  61.         bra     loop_test
  62.  
  63. loop:        cmp.l    mlen,len
  64.         bge    sk01
  65.         move.l    len,mlen
  66. sk01:        sub.l    mlen,len
  67.         movea.l    M_DATA(m),w
  68. * 
  69.         tst.l    spanning
  70.         beq.s    no_spanning
  71. *
  72. * The first byte of this mbuf is the continuation
  73. * of a word spanning between this mbuf and the
  74. * last mbuf.
  75. *
  76.         move.l    zero,d0
  77.         move.b    (w)+,d0
  78.         add.l    d0,sum
  79.         addx.l    zero,sum
  80.         addx.l    zero,sum
  81.         ; End of buffer?
  82.         subq.l    #1,mlen
  83.         move.l    mlen,spanning
  84.         beq.w    next
  85. *
  86. * Force to word boundary
  87. *
  88. no_spanning:    move.l    w,byte_swapped
  89.         andi.l    #1,byte_swapped
  90.         beq.s    onword
  91. *
  92. * Swap sum bytes
  93. *
  94.         rol.l    #8,sum    
  95.         move.l    zero,d0
  96.         move.b    (w)+,d0
  97.         add.l    d0,sum
  98.         addx.l    zero,sum
  99.         addx.l    zero,sum
  100.         subq.l    #1,mlen
  101. *
  102. * Force to long boundary
  103. *
  104. onword:        move.l    w,d0
  105.         andi.b    #3,d0
  106.         beq    onlong
  107.         moveq    #-2,d0
  108.         add.l    mlen,d0
  109.         blt    loop2out
  110.         move.l    d0,mlen
  111.         add.w    (w)+,sum
  112.         addx.l    zero,sum
  113.         addx.l    zero,sum
  114. onlong:        move.l    mlen,d0
  115.         ror.l    #5,d0
  116.         add.l    zero,zero    ; clear X
  117.         bra    loop32test
  118. *
  119. * Main loop
  120. *        
  121. loop32:        move.l    (w)+,d1
  122.         addx.l    d1,sum
  123.         move.l    (w)+,d1
  124.         addx.l    d1,sum
  125.         move.l    (w)+,d1
  126.         addx.l    d1,sum
  127.         move.l    (w)+,d1
  128.         addx.l    d1,sum
  129.         move.l    (w)+,d1
  130.         addx.l    d1,sum
  131.         move.l    (w)+,d1
  132.         addx.l    d1,sum
  133.         move.l    (w)+,d1
  134.         addx.l    d1,sum
  135.         move.l    (w)+,d1
  136.         addx.l    d1,sum
  137. loop32test:    dbf.s    d0,loop32
  138.         moveq    #31,d0
  139.         and.l    mlen,d0
  140.         ror.l    #2,d0
  141.         bra.s    loop4test
  142. loop4:        move.l    (w)+,d1
  143.         addx.l    d1,sum    
  144. loop4test:    dbf    d0,loop4
  145. *            
  146. * A single word still in mbuf?
  147. *
  148.         moveq    #2,d0
  149.         and.l    mlen,d0
  150.         beq    loop2out
  151.         move.w    (w)+,d1
  152.         addx.w    d1,sum
  153. *
  154. * A single byte still in mbuf?
  155. *
  156. loop2out:    addx.l    zero,sum
  157.         addx.l    zero,sum
  158.         moveq    #1,spanning
  159.         and.l    mlen,spanning
  160.         beq    loop1out
  161.         move.l    zero,d0
  162.         move.b    (w)+,d0
  163.         rol.l    #8,d0
  164.         addx.w    d0,sum
  165.         addx.l    zero,sum
  166.         addx.l    zero,sum
  167.  
  168. loop1out:    tst.l    byte_swapped
  169.         beq    next
  170.         ; bytes were swapped, swap them back
  171.         rol.l    #8,sum
  172.         ; Invert spanning status
  173.         subq.l    #1,spanning        
  174. next:        movea.l    M_NEXT(m),m
  175. loop_test:    move.l    m,d0
  176.         beq.s    return
  177.         tst.l    len
  178.         beq.s    return
  179. *        if (m->m_len == 0)
  180. *            continue;
  181.         move.l    M_LEN(m),mlen
  182.         beq.s    next
  183.         bra.w    loop
  184. return:        tst.l    len
  185.         beq.s    reduce
  186.         pea    out_of_data(pc)
  187.         jsr    _printf(pc)
  188.         addq.l    #4,sp
  189. *
  190. * Reduce
  191. *
  192. reduce:        move.l    zero,d0
  193.         move.w    sum,d0
  194.         swap    sum
  195.         add.w    sum,d0
  196.         addx.w    zero,d0
  197.         eori.w    #$ffff,d0
  198.         movem.l    (a7)+,d2-d7/a2/a3/a5/a6
  199.         rts
  200.         
  201. out_of_data:    dc.b    'cksum: out of data',10,0
  202.         
  203.         end
  204.